procedure MyForm.Button1Click(Sender: TObject);
var
  i, j: integer;
  lString: string;
begin
  lString := '';
  for i := 0 to Grid.RowCount - 1 do begin
    for j := 0 to Grid.ColCount - 1 do begin
      lString := lString + Grid.Cells[j, i];
      if j < Grid.ColCount - 1 then
        lString := lString + #9;
    end;
    if i < Grid.RowCount - 1 then
      lString := lString + #13;
  end;
  Clipboard.AsText := lString;
end;

With few modifications this code can be also applied to TDrawGridEx.

unit XMLConfig;

interface

uses
  Forms, SysUtils, Windows, XmlIntf, XMLDoc;

type
  TXMLConfig = class
  private
    FModified: Boolean;
    FFileName: string;
    FXMLDoc: TXMLDocument;
    FBackup: Boolean;
    function GetVersion: string;
  public
    constructor Create(const FileName: string); overload;
    constructor Create; overload;
    destructor Destroy; override;
    procedure Save;
    function ReadString(const Section, Key,
                               default: string): string;
    procedure WriteString(const Section, Key,
                               Value: string);
    function ReadInteger(const Section, Key: string;
                                 default: Integer): Integer;
    procedure WriteInteger(const Section, Key: string;
                                    Value: Integer);
    function ReadBoolean(const Section, Key: string;
                                default: Boolean): Boolean;
    procedure WriteBoolean(const Section, Key: string;
                                    Value: Boolean);
    property Backup: Boolean read FBackup write FBackup;
    property Version: string read GetVersion;
  end;

implementation

{ TXMLConfig }

constructor TXMLConfig.Create(const FileName: string);
begin
  inherited Create;
  FBackup         := True;
  FFileName       := FileName;
  FXMLDoc         := TXMLDocument.Create(Application);
  FXMLDoc.Options := [doNodeAutoIndent];
  if FileExists(FFileName) then
    FXMLDoc.LoadFromFile(FFileName)
  else
  begin
    FXMLDoc.Active := True;
    FXMLDoc.AddChild('Configuration');
  end;
end;

constructor TXMLConfig.Create;
begin
  Create(ChangeFileExt(Application.Exename, '_cfg.xml'));
end;

destructor TXMLConfig.Destroy;
begin
  Save;
  FXMLDoc.Destroy;
  inherited;
end;

function TXMLConfig.GetVersion: string;
begin
  Result := '1.00';
end;

function TXMLConfig.ReadBoolean(const Section, Key: string; default: Boolean): Boolean;
begin
  Result := Boolean(ReadInteger(Section, Key, Integer(default)));
end;

function TXMLConfig.ReadInteger(const Section, Key: string; default: Integer): Integer;
begin
  Result := StrToInt(ReadString(Section, Key, IntToStr(default)));
end;

function TXMLConfig.ReadString(const Section, Key, default: string): string;
var
  Node: IXMLNode;
begin
  Node := FXMLDoc.DocumentElement.ChildNodes.FindNode(Section);
  if Assigned(Node) and Node.HasAttribute(Key) then
    Result := Node.Attributes[Key]
  else
    Result := default;
end;

procedure TXMLConfig.Save;
begin
  if not FModified then
    Exit;
  if FBackup then

    CopyFile(PChar(FFileName), PChar(FFileName + '.bak'), False);
  FXMLDoc.SaveToFile(FFileName);
  FModified := False;
end;

procedure TXMLConfig.WriteBoolean(const Section, Key: string; Value: Boolean);
begin
  WriteInteger(Section, Key, Integer(Value));
end;

procedure TXMLConfig.WriteInteger(const Section, Key: string; Value: Integer);
begin
  WriteString(Section, Key, IntToStr(Value));
end;

procedure TXMLConfig.WriteString(const Section, Key, Value: string);
var
  lNode: IXMLNode;
begin
  if ReadString(Section, Key, '') = Value then
    Exit;
  lNode := FXMLDoc.DocumentElement.ChildNodes.FindNode(Section);
  if not Assigned(lNode) then
    lNode := FXMLDoc.DocumentElement.AddChild(Section);
  lNode.Attributes[Key] := Value;
  FModified := True;
end;

end.

procedure AForm.Button1Click(Sender: TObject);
var b : BForm;
begin
  b := BForm.Create(nil);
  try
    if b.ShowModal = mrOk then begin
      // your code if OK Button is clicked
    end
    else begin
      // your code, if cancel is clicked
    end;
  finally
      b.Release;
  end;
end;

On your BForm you need two Buttons. One of them you use for Ok and the other one for Cancel. The only thing you need to do is to chage respectively the ModalResult property of these buttons as shown in the picture bellow:

That’s all. Notice, that the value of the Visible-property of your BForm should be false.

To raise an exception:

raise Exception.Create('Your exception message');

Excepion is general exception class. Of course you can define your own Exception classes.

To catch exceptions you have several options:

try
  // your code
except
  // exception handling
end;

try
  // your code
except on e:Exception do
  // exception handling, for example :
  showmessage(E.Message);
end;

The combination of except and finally sections looks like this:

try
    try
       // your code
    except on e:exception do begin
       // exception handling
    end;
finally
    // finally section
end;

type
  TForm1 = class(TForm)
    MyButton1: TButton;
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
    procedure MyBtnClick(Sender: TObject);
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.MyButtonClick(Sender: TObject);
begin
  ShowMessage('Button is clicked!');
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  MyButton1 := TButton.Create(Form1);
  MyButton1.Parent := Form1;
  MyButton1.OnClick := MyButtonClick;
end;

In this simple case MyButtonClick is a class method. The way it’s used in the example above is quite usual. But what to do if you need to use some method to handle OnClick event, which is defined outside the class(external function)? In this situation you have to wrap up your method by a record:

type
  TMethodPointer = packed record
    pMethod: Pointer;
    pObject: TObject;
end;

After this you can add your event handler, using casting to TNotifyEvent like this:

methodPointer.pMethod := @MyOnClickMethod;
methodPointer.pObject := nil;
MyButton1.OnClick :=  TNotifyEvent(methodPointer);